DDR爱好者之家

ASP下通过Adodb.Stream实现多线程下载大文件
站长资源 2024/11/24 佚名
68 1538
DDR爱好者之家 Design By 杰米

有个朋友 做 某种小众音乐交换站的（他们那个行业的昵图网），需要用到付费下载。尝试过 防盗链，不太理想，最终使用了 Adodb.Stream 读取，直接输出。

解决了 盗版的问题，但是新的问题又来了。Adodb.Stream 这种方式 电脑还好说，大部分电脑浏览器都支持。移动端 很多 浏览器为了 加速读取，会多线程下载导致 文件无法正常读取。

抓包，发现增加了 HTTP头 HTTP_RANGE。隐约记得 之前读过 王大（王洪影）的 《深入解析 ASP核心技术》当中提到ASP多线程下载的问题，回家翻出来，最终还就真解决了。

为了 方便调用，直接写成了 一个 函数。没用王大的代码，感觉我自己的更美（自恋中…）。如有有需要的朋友需要，直接拿走即可，代码如下：

option explicit
 
'inputFile 需要下载的文件
'outputName 输出文件名，可以为空，为空时自动根据 inputFile 生成
Sub CreateDownloader(byval inputFile, byval outputName)
  Dim filePath
  filePath = Server.Mappath(inputFile)
  If outputName = "" Then outputName = Split(filePath, "\")(UBound(Split(filePath, "\")))
 
  '下载开始
  Dim AdoStream, bufferSize
  Set AdoStream = Server.CreateObject("Adodb.Stream") 'Adodb.Stream，实例变量名为了方便区分用大写
  bufferSize   = 2 * 1024 * 1024 '每次读取大小(byte) 2M
  AdoStream.Mode = 3 '1 读，2 写，3 读写
  AdoStream.Type = 1 '1 二进制，2 文本
  AdoStream.Open
  AdoStream.LoadFromFile(filePath) '载入文件
  Response.AddHeader "Content-Disposition", "attachment; filename=" & outputName '文件名
  Response.ContentType = "application/octet-stream" '通知浏览器接受的文件类型(可自己定义,很多种,但一般都用这个
 
  Dim httpRange,rangeStart,fileSize
  '获取 分段下载 请求
  httpRange = Request.ServerVariables("HTTP_RANGE")
  fileSize = AdoStream.size '文件总大小
 
  If httpRange = "" Then
    '不支持断点续传
    rangeStart = 0
  Else
    '支持断点续传
    httpRange = Mid(httpRange, 7)
    rangeStart = CLng(Split(httpRange, "-")(0))
 
    If rangeStart < 0 Or rangeStart >= fileSize Then
      '已经下载完毕
      Response.Status = "416 Requested range not satisfiable"
    Else
      Response.Status = "206 Partial Content"
      Response.AddHeader "Content-Range", "bytes " & rangeStart & "-" & (fileSize - 1) & "/" & fileSize
      AdoStream.Position = rangeStart
    End If
 
  End If
 
  Dim binaryBlock
 
  If Response.Status <> "416 Requested range not satisfiable" Then
    Response.AddHeader "Content-Length", fileSize - rangeStart '通知浏览器接收的文件大小
    binaryBlock = AdoStream.Read(bufferSize)
 
    Do While Lenb(binaryBlock) > 0 '循环读取直到读完为止
      Response.BinaryWrite binaryBlock '输出二进制数据流
      Response.Flush '立即发送(要求至少256字节)，不加的话可能提示超过缓存区。
      binaryBlock = AdoStream.Read(bufferSize)
    Loop
 
  End If
 
  AdoStream.Close '关闭文件对象
  Set AdoStream = Nothing
  Response.End
End Sub

使用也非常简单，假如上面的代码保存到了 downloader.asp，直接引用即可：

<!--#include file="downloader.asp"-->
<%
  '创建下载
  call CreateDownloader("down/tools.rar", "")
   
  '创建下载并自定义文件名
  call CreateDownloader("down/tools.rar", "hello.rar")
%>

有图有真相：

ASP下通过Adodb.Stream实现多线程下载大文件

DDR爱好者之家 Design By 杰米
广告合作：本站广告合作请联系QQ：858582 申请时备注：广告合作（否则不回）
免责声明：本站资源来自互联网收集,仅供用于学习和交流,请遵循相关法律法规,本站一切资源不代表本站立场,如有侵权、后门、不妥请联系本站删除！
DDR爱好者之家 Design By 杰米
ddrfans.com DDR爱好者之家
8,675无损音乐
1,324高清电影
213破解软件
70,141收录资讯

《魔兽世界》大逃杀！60人新游玩模式《强袭风暴》3月21日上线

暴雪近日发布了《魔兽世界》10.2.6 更新内容，新游玩模式《强袭风暴》即将于3月21 日在亚服上线，届时玩家将前往阿拉希高地展开一场 60 人大逃杀对战。

艾泽拉斯的冒险者已经征服了艾泽拉斯的大地及遥远的彼岸。他们在对抗世界上最致命的敌人时展现出过人的手腕，并且成功阻止终结宇宙等级的威胁。当他们在为即将于《魔兽世界》资料片《地心之战》中来袭的萨拉塔斯势力做战斗准备时，他们还需要在熟悉的阿拉希高地面对一个全新的敌人──那就是彼此。在《巨龙崛起》10.2.6 更新的《强袭风暴》中，玩家将会进入一个全新的海盗主题大逃杀式限时活动，其中包含极高的风险和史诗级的奖励。

《强袭风暴》不是普通的战场，作为一个独立于主游戏之外的活动，玩家可以用大逃杀的风格来体验《魔兽世界》，不分职业、不分装备（除了你在赛局中捡到的），光是技巧和战略的强弱之分就能决定出谁才是能坚持到最后的赢家。本次活动将会开放单人和双人模式，玩家在加入海盗主题的预赛大厅区域前，可以从强袭风暴角色画面新增好友。游玩游戏将可以累计名望轨迹，《巨龙崛起》和《魔兽世界：巫妖王之怒 经典版》的玩家都可以获得奖励。

更新日志

友情链接

杰晶网络 DDR爱好者之家 南强小屋 黑松山资源网 白云城资源网
DDR爱好者之家 Design By 杰米